***EViews* Exercises for Chapter 14**

**Spurious regressions**

**[14.6]** The statistics used in the construction of Table 14.1 may be obtained, after starting *EViews* *10*, by clicking ***Create a new EViews workfile***, selecting ‘Unstructured/Undated’ as the ‘Workfile structure type’ and entering 1000 for ‘observations’. The simulations are obtained with the program spurious\_reg.prg:

!reps = 1000

matrix(!reps,3) res1

for !i = 1 to !reps

smpl 1 1

genr x{!i} = 0

genr u{!i} = 0

smpl 2 51

genr v{!i} = @nrnd

genr e{!i} = @nrnd

genr x{!i} = x{!i}(-1) + v{!i}

genr u{!i} = u{!i}(-1) + e{!i}

genr y{!i} = u{!i}

equation eqn1{!i}.ls y{!i} x{!i} c

res1(!i,1) = eqn1{!i}.@tstats(1)

res1(!i,2) = eqn1{!i}.@r2

res1(!i,3) = eqn1{!i}.@dw

d x{!i}

d u{!i}

d v{!i}

d e{!i}

d y{!i}

d eqn1{!i}

next

smpl 1 !reps

series t\_stat\_static

series rsq\_static

series dw\_static

group g1 t\_stat\_static rsq\_static dw\_static

mtos(res1,g1)

genr abs\_t\_stat\_static = abs(t\_stat\_static)

genr diff = rsq\_static - dw\_static

The frequency distributions of the series abs\_t\_stat\_static, rsq\_static and dw\_static may be obtained with ***View/One-Way Tabulation…***, bearing in mind that each run of the program will produce slightly different statistics.

**[14.10-14.12]** Figures 14.1-14.5 are obtained by running yule\_spurious.prg:

!reps = 1000

!n = 100

matrix(!reps,5) res1

for !i = 1 to !reps

smpl 1 1

genr x{!i} = 0

genr y{!i} = 0

smpl 2 !n+1

genr v{!i} = @nrnd

genr u{!i} = @nrnd

genr x{!i} = x{!i}(-1) + v{!i}

genr y{!i} = y{!i}(-1) + u{!i}

res1(!i,1) = @cor(v{!i}, u{!i})

res1(!i,2) = @cor(x{!i}, y{!i})

res1(!i,5) = @cor(x{!i}, u{!i})

smpl 1 2

genr w{!i} = 0

genr z{!i} = 0

smpl 3 !n+2

genr w{!i} = w{!i}(-1) + x{!i}

genr z{!i} = z{!i}(-1) + y{!i}

res1(!i,3) = @cor(w{!i},z{!i})

res1(!i,4) = @cor(w{!i},y{!i})

d x{!i}

d u{!i}

d v{!i}

d y{!i}

d w{!i}

d z{!i}

next

smpl 1 !reps

series r00

series r11

series r22

series r12

series r01

group g1 r00 r11 r22 r12 r01

mtos(res1,g1)

The frequency distributions of the series r00, r11, r22, r12 and r01 are shown in Figures 14.1-14.5 respectively.

**[14.15]** Table 14.2 and Figures 14.6 and 14.7 are obtained with the program spurious\_ardl.prg:

!reps = 1000

matrix(!reps,8) res2

for !i = 1 to !reps

smpl 1 1

genr x{!i} = 0

genr u{!i} = 0

smpl 2 51

genr v{!i} = @nrnd

genr e{!i} = @nrnd

genr x{!i} = x{!i}(-1) + v{!i}

genr u{!i} = u{!i}(-1) + e{!i}

genr y{!i} = u{!i}

equation eqn2{!i}.ls y{!i} x{!i} x{!i}(-1) y{!i}(-1) c

res2(!i,1) = eqn2{!i}.@tstats(1)

res2(!i,2) = eqn2{!i}.@coefs(1)

res2(!i,3) = eqn2{!i}.@tstats(2)

res2(!i,4) = eqn2{!i}.@coefs(2)

res2(!i,5) = eqn2{!i}.@coefs(3)

res2(!i,6) = eqn2{!i}.@r2

res2(!i,7) = eqn2{!i}.@dw

res2(!i,8) = eqn2{!i}.@stderrs(3)

d x{!i}

d u{!i}

d v{!i}

d e{!i}

d y{!i}

d eqn2{!i}

next

smpl 1 !reps

series t\_1\_dl

series beta\_1\_dl

series t\_2\_dl

series beta\_2\_dl

series gamma\_dl

series rsq\_dl

series dw\_dl

series se\_gamma

group g2 t\_1\_dl beta\_1\_dl t\_2\_dl beta\_2\_dl gamma\_dl rsq\_dl dw\_dl se\_gamma

mtos(res2, g2)

genr abs\_t\_1\_dl = abs(t\_1\_dl)

genr abs\_t\_2\_dl = abs(t\_2\_dl)

genr h = (1 - 0.5\*dw\_dl)\*@sqrt(50/(1 - 50\*(se\_gamma^2)))

**EXAMPLE 14.1: Are U.K. interest rates cointegrated?**

This example uses the workfile interest\_rates.wk1. The Engle-Granger test statistics may be obtained automatically by opening r20, rs as a group and clicking ***View/Cointegration Test/Single Equation Cointegration Test…***. The ADF-type regressions may be obtained by running the regressions

ls r20 c rs

ls rs c r20

in each case saving the residuals using ***Proc/Make residual series…*** and then running a standard unit root test on each residual series resid01, resid02. Of course, the p-values associated with the unit root tests will be incorrect here as the residuals are treated as observed series.

The bounds tests and accompanying CECs may be obtained from the above regressions by choosing the ARDL estimation method with ‘1. None’ as the Trend specification and then clicking ***View/Error Correction Form***.

**EXAMPLE 14.2: Estimating a cointegrating relationship between U.K. interest rates**

OLS estimates of the cointegrating relationship between r20 and rs are given by

ls r20 c rs

To obtain the FM-OLS estimates, click ***Estimate*** and choose ‘COINTREG – Cointegrating Regression’ as the Estimation method. FM-OLS is the default choice so clicking OK will obtain these estimates. Repeating but selecting ‘Dynamic OLS (DOLS)’ as the method then obtains the DOLS estimates.

The CEC cointegration relationship may be obtained by choosing ‘ARDL’ as the estimation method, selecting ‘2. Rest. Constant’ for the Trend Specification, and then clicking ***View/Coefficient Diagnostics/Long Run Form and Bounds Test***, whereupon the ‘long-run’ form will be displayed. These commands may then be repeated with the ordering of the series reversed to obtain the various estimates for the cointegrating relationship between rs and r20.

To estimate the error correction models containing the spread, use the equation commands

ls d(r20) = c(1)\*(r20(-1) – rs(-1) – c(2)) + c(3)\*d(rs) + c(4)\*d(rs(-1)) + c(5)\*d(r20(-1)) + c(6)\*d(r20(-2))

ls d(rs) = c(1)\*(r20(-1) – rs(-1) – c(2)) + c(3)\*d(r20) + c(4)\*d(rs(-1))

**EXAMPLE 14.3: Error correction modelling of global temperatures**

Open the workfile global\_forcings.prg and click ***Quick/Estimate*** and choose ARDL as the estimation method. Enter

temp trf vol soi amo

as the list of variables and choose ‘2. Rest. constant’ for the Trend specification. Clicking ***View/Coefficient Diagnostics/Long Run Form and Bounds test*** will produce the required statistics. Repeating the commands but with only temp trf in the variable list and

vol vol(-1) soi soi(-1) amo amo(-1)

as the list of exogenous variables will estimate the model containing only temp and trf in the error correction.